:"Snake Arcade Gen III
1.09
[CLASSIC]
ClrHome
If det([[1:Then
	Disp "Celtic 3 Is","Not Installed!
	Pause 
	ClrHome:Return
End
DelVar M
If getKey
getKey
"rowSwap(SnakeARC->Str9
FnOff 
PlotsOff 
AxesOff
GridOff
ZStandard
ZInteger
Lbl ZS
real(7,0
For(I,94,34,~1
	Text(15,I,"S  N  A  K  E
End
real(12,3,0,0,95,63,1
If M
Text(1,2,"MIRAGE OS:
For(I,35,23,~1
	Text(~1,I,16,"A r c a d e
End
real(12,8,2,14,93,35,1
For(I,4,91
	Pxl-Off(33,I
End
Text(36,2,"BIO_HAZARD1282_RPI3
Text(42,2,"VERSION ",det(5,"SNKEARC",2
6->A:2->B
randInt(1,20->D
randInt(1,20->E
Text(56,24,"PRESS ANY KEY!
startTmr->T
C+1->C
"O0DHMN|NZIGQXthetaxmark#@SigmaOmegainvertedequalmathprintbox->Str1
"*plotdotplotcrossplotsquareoxintegralxmarksquareroot%&\/small0gammaDeltadeltaPhi+$->Str2
startTmr->theta
Repeat getKey or 14<checkTmr(theta
	C+1->C
	If C>2:Then
		A+1-11(A=11->A
		B+1-11(B=11->B
		Text(~1,4,2+7A,sub(Str1,D,1
		If A=5
		Text(~1,4,79,sub(Str2,E,1
		Text(~1,4,2+7B," 
		0->C
	End
	If checkTmr(T:Then
		real(12,8,1,56,94,62,1
		startTmr->T
End:End
If 15>checkTmr(theta
Goto SS
real(5->C
For(I,C,0,~1
	real(5,0,I
	rand(2
End
rand(100
DelVar SClrDraw
real(7,0
real(12,6,0,6,93,63
real(12,7,0,29,93,33,1
Line(Xmin,0,0,0
Text(0,0,"DEMO
For(I,0,C
	real(5,0,I
	rand(2
End
rand(100
Repeat getKey
	Pxl-On(31,47
	real(4,2,1,1
	S+pxl-Test(30,47)pxl-Test(32,47->S
	Text(0,0,"DEMO
	Text(randInt(0,57),91,"=
	If pxl-Test(31,47:Then
		randInt(0,1
		If pxl-Test(30,47)not(pxl-Test(32,47:0
		If pxl-Test(32,47)not(pxl-Test(30,47:1
		real(4,Ans,1,1
	End
End
real(12,7,2,27,93,35,1
real(12,3,2,27,93,35,1
46-2(S>9)-2(S>99)-2(S>999
Text(28,Ans,S
rand(200
For(I,C,0,~1
	real(5,0,I
	rand(2
End
ClrDraw
real(7,0
rand(100
For(I,0,C
	real(5,0,I
	rand(2
End
Goto ZS
Lbl SS
real(12,7,1,1,94,62,1
real(13,1
Text(~1,1,1,"Booting Game...
Text(~1,1,89," 
real(13,0
det(0,7,Str9
If Ans=".P:NT:FN":Then
	real(13,1
	Text(~1,1,1,"No User Found! 
	real(13,0
	Text(9,2,"NO USER HAS BEEN MADE
	Text(15,2,"FOR THIS GAME. PLEASE
	Text(21,2,"REGISTER A USER FIRST
	Text(27,2,"BEFORE PLAYING.
	Pause 
	ClrDraw:ClrHome
	Return
End
Text(9,2,"VALIDATING
Text(15,2,"SAVE DATA.
real(12,3,0,60,95,63,1
DelVar E
For(I,1,10
	det(17,det(5,Str9,I->Str3
	If I!=3:Then
		For(J,1,length(Str3
			sub(Str3,J,1
			If not(inString("{,0123456789}",Ans
			1->E
		End
	Else
		For(J,1,length(Str3
			sub(Str3,J,1
			If not(inString("ABCDEFGHIJKLMNOPQRSTUVWXYZ_",Ans
			1->E
	End:End
	int(100I/10
	int(Ans%94
	real(12,6,0,60,Ans,63,1
End
If E:Then
	real(13,1
	Text(~1,1,1,"Data Corrupted!
	real(13,0
	real(12,7,1,9,94,62,1
	Text(9,2,"THE SAVE DATA IS INVALID
	Text(15,2,"AND CANNOT BE USED.
	Text(27,2,"PLEASE REGISTER A NEW
	Text(33,2,"USER TO CONTINUE PLAYING.
	Pause 
	ClrDraw:ClrHome
	Return
End
Text(9,2,"READING AND
Text(15,2,"DECOMPRESSING DATA.
real(12,7,0,60,95,63,1
real(12,3,0,60,95,63,1
SetUpEditor STAT,SET,LVL,NMH,NIH,SPH,DMH,SKN,FOD
For(I,1,10
	If I!=3:Then
		expr(det(17,det(5,Str9,I
		If I=1
		Ans->STAT
		If I=2
		Ans->SET
		If I=4
		Ans->LVL
		If I=5
		Ans->NMH
		If I=6
		Ans->NIH
		If I=7
		Ans->SPH
		If I=8
		Ans->DMH
		If I=9
		Ans->SKN
		If I=10
		Ans->FOD
	Else
		det(17,det(5,Str9,3->Str4
	End
	int(100I/10
	int(Ans%94
	real(12,6,0,60,Ans,63,1
End
If not(|LSET(5
Goto M
Lbl UP
0->D
real(13,1
Text(~1,1,1,"Finding Updates 
real(13,0
real(12,7,1,9,94,62,1
"rowSwap(SnkArcUp->Str8
det(0,7,Ans
det(0,7,Str8
If Ans=".P:NT:FN":Then
	real(13,1
	Text(~1,1,1,"Update Missing!
	real(13,0
	Text(9,2,"THE UPDATE FILE IS
	Text(15,2,"MISSING AND CANNOT BE
	Text(21,2,"USED FOR UPDATING.
	Pause 
	ClrDraw:ClrHome
	1->D
End
If D
Goto M
DelVar E
det(5,Str8
If Ans<2
1->E
det(5,Str8,2
sub(Ans,2,1
If Ans!="." or 4!=length(det(5,Str8,2
1->E
If not(E:Then
	length(det(5,Str8,2->L
	For(I,1,L
		If I!=2:Then
			sub(det(5,Str8,2),I,1
			If not(inString("0123456789",Ans
			1->E
		End
End:End
If E:Then
	real(13,1
	Text(~1,1,1,"Invalid Version
	real(13,0
	Text(9,2,"THE UPDATE VERSION
	Text(15,2,"CANNOT BE READ CORRECTLY.
	Pause 
	ClrDraw:ClrHome
	1->D
End
If D
Goto M
expr(det(5,"SNKEARC",2->A
expr(det(5,Str8,2->B
0->U
If A<B:Then
	det(0,7,"SNKEARUP
	If Ans!=".P:NT:FN":Then
		sub(det(0,7,"SNKEARUP"),1,1
		If Ans="A
		det(0,"SNKEARUP
		1->U
End:End
If U:Then
	prgmSNKEARUP
	ClrDraw
	real(7,|LSET(2
End
Lbl M
ClrDraw
real(5,0,|LSET(1
real(7,|LSET(2
|LSKN(|LSTAT(3
If Ans<1
1->|LSTAT(3
If not(|LSKN(1
1->|LSKN(1
|LFOD(|LSTAT(4
If Ans<1
1->|LSTAT(4
If not(|LFOD(1
1->|LFOD(1
real(12,3,0,0,95,63,1
real(13,1
Text(~1,1,1,"Snake Arcade   
Text(~1,1,89," 
real(13,0
Text(9,2,"PLAY
Text(15,2,"STORE
Text(21,2,"MY DATA
Text(27,2,"HIGH SCORES
Text(33,2,"OPTIONS
Text(39,2,"QUIT
Text(56,2,"HI, "+Str4,"!
|LSTAT(5->P
Text(56,91-4(P>9)-4(P>99)-4(P>999)-4(P>9999),P
9->O
If not(pxl-Test(0,0:Then
	real(12,3,0,0,95,63,1
	real(7,|LSTAT(2
End
Repeat max(K={21,105,31
	real(12,8,1,O,94,O+6,1
	Repeat K
		getKey->K
	End
	real(12,8,1,O,94,O+6,1
	max(9,min(39,O+6(K=34)-6(K=25->O
End
If K=31
Goto UP
If O=9
Goto PL
If O=15
Goto S
If O=21
Goto MD
If O=27
Goto HS
If O=33
Goto OP
If O=39
Goto Q
Lbl OP
real(13,1
Text(~1,1,1,"Options        
real(13,0
real(12,7,1,9,94,62,1
Text(9,2,"CHANGE SKINS
Text(15,2,"SET CONTRAST
Text(21,2,"RUN INDICATOR
Text(27,2,"ARC ON EXIT
Text(33,2,"ASK TO SAVE
Text(39,2,"UPDATE CHECKS
Text(45,2,"CHANGE NAME
Text(51,2,"SET
9->O
Lbl S0
Text(15,62,|LSET(1
For(I,1,4
	{21,27,33,39
	Text(Ans(I),62,sub("NY",1+|LSET(I+1),1
End
Text(45,62,Str4
Repeat max(K={21,105,23
	real(12,8,1,O,60,O+6,1
	Repeat K
		getKey->K
	End
	real(12,8,1,O,60,O+6,1
	max(9,min(51,O+6(K=34)-6(K=25->O
End
If K=23
Goto RS
If O=9
Goto S1
If O=15
Goto S2
If O=45
Goto S3
If O=51
Goto M
If O=21
not(|LSET(2->|LSET(2
If O=27
not(|LSET(3->|LSET(3
If O=33
not(|LSET(4->|LSET(4
If O=39
not(|LSET(5->|LSET(5
Goto S0
Lbl GO
real(13,1
Text(~1,1,1,"Game Over!     
"NORMAL
If M=2
"DIMENTED
If M=3
"SPACE
If M=4
"NIBBLES
Text(1,60,Ans
real(13,0
real(12,7,1,9,94,62,1
Text(10,2,"YOUR SCORE:
If M=3:Then
	91-4(R>9)-4(R>99)-4(R>999)-4(R>9999
	Text(10,Ans,R
End
Text(~1,10,41,0
rand(50
For(I,1,S
	Text(~1,10,41,I
End
If W:Then
	rand(50
	real(12,3,2,18,93,32,1
	Text(19,4,"NEW HIGH SCORE!
	{5,8,3,4
	Ans(M->N
	Text(25,4,"+",N," GOLD
	N+|LSTAT(1->|LSTAT(1
Else
	real(12,3,2,18,93,26,1
	Text(19,4,"+2G FOR TRYING! :)
	2+|LSTAT(1->|LSTAT(1
End
Text(34,2,"TOTAL:
Text(~1,34,24,|LLVL(4
rand(50
For(I,1,S
	1+|LLVL(4->|LLVL(4
	Text(~1,34,24,Ans
End
real(12,3,0,60,95,63,1
Text(42,4,"LEVEL:
|LLVL
Text(~1,42,26,Ans(2
Text(53,2,Ans(1
Text(53,18,"/",|LLVL(3
int(100Ans(1)/Ans(3
int(Ans%94
real(12,6,0,60,Ans,63,1
rand(50
For(I,1,S
	1+|LLVL(1
	If Ans=|LLVL(3:Then
		Text(53,2,Ans
		real(12,7,0,60,95,63,1
		real(12,3,0,60,95,63,1
		0->|LLVL(1
		1+|LLVL(2->|LLVL(2
		Text(~1,42,26,Ans
		3Ans->N
		Text(42,46,"+",Ans,"G
		rand(50
		Text(42,46,"                       
		N+|LSTAT(1->|LSTAT(1
		25+|LLVL(3->|LLVL(3
		Text(53,2,"0           
		Text(53,18,"/",Ans
	0:End
	Ans->|LLVL(1
	Text(53,2,Ans
	int(100Ans(1)/|LLVL(3
	int(Ans%94
	real(12,6,0,60,Ans,63,1
End
Pause 
Goto M
Lbl PL
real(12,7,1,9,94,62,1
real(13,1
Text(~1,1,1,"Select Mode!   
real(13,0
Text(9,2,"NORMAL
Text(15,2,"DIMENTED
Text(21,2,"SPACE
Text(27,2,"NIBBLES
Text(33,2,"BACK
real(12,0,2,40,93,40,1
Text(42,4,"SKIN: 
Text(~1,42,22,sub(Str1,|LSTAT(3),1
Text(42,28,"x",|LSKN(|LSTAT(3
Text(49,4,"FOOD: x
Text(~1,49,22,sub(Str2,|LSTAT(4),1
Text(49,28,"x",|LFOD(|LSTAT(4
9->O
Repeat max(K={21,105
	real(12,8,1,O,94,O+6,1
	Repeat K
		getKey->K
	End
	real(12,8,1,O,94,O+6,1
	max(9,min(33,O+6(K=34)-6(K=25->O
End
If O=33
Goto M
1+|LSTAT(5->|LSTAT(5
0->W
1->M
If O=15
2->M
If O=21
3->M
If O=27
4->M
If O=21
Goto M3
If O=27
Goto M4
sub(Str1,|LSTAT(3),1->Str5
sub(Str2,|LSTAT(4),1->Str6
|LSTAT(3
|LSKN(Ans)-1->|LSKN(Ans
|LSTAT(4
|LFOD(Ans)-1->|LFOD(Ans
If O=9
Goto M1
If O=15
Goto M2
Lbl M4
ClrDraw
ZStandard
104->Xmax
~72->Ymin
ZInteger
real(7,|LSET(2
real(12,3,0,0,94,61,1
41->A:Ans->E
29->B:Ans->F
1->H:0->V
5->S:0->theta
0->D
Pt-On(41,~29,2
Repeat not(pxl-Test(N-1,M-1
	2+3int(31rand->M
	2+3int(20rand->N
End
Pt-On(M,~N,2
Pt-Off(M,~N,3
Pxl-On(N,M
Repeat D or K=45
	getKey->K
	If Ans:Then
		If H:Then
			(Ans=34)-(Ans=25->V
			If Ans
			0->H
		Else
			(Ans=26)-(Ans=24->H
			If Ans
			0->V
		End
	End
	If H:Then
		A+3H->A
		If pxl-Test(B,Ans-H
		1->D
		A
		Pt-On(Ans,~B,2
		Pxl-Off(B,Ans-H
		Pxl-Off(B,Ans-2H
	Else
		B+3V->B
		If pxl-Test(Ans-V,A:1->D
		B
		Pt-On(A,~Ans,2
		Pxl-Off(Ans-V,A
		Pxl-Off(Ans-2V,A
	End
	If D
	Goto SQ
	If pxl-Test(B,A:Then
		Pxl-Off(B,A
		Repeat not(pxl-Test(N-1,M-1
			2+3int(31rand->M
			2+3int(20rand->N
		End
		Pt-On(M,~N,2
		Pt-Off(M,~N,3
		Pxl-On(N,M
		Pxl-On(62,theta
		theta+1->theta
		If Ans=95
		1->D
		S+3->S
	End
	If D
	Goto SQ
	If S:Then
	S-1->S:Else
		pxl-Test(F,E-1)-pxl-Test(F,E+1
		If Ans:Then
			Pxl-On(F,E+2Ans
			Pt-Off(E,~F,2
			E+3Ans->E
		Else
			1-2pxl-Test(F+1,E
			Pxl-On(F+2Ans,E
			Pt-Off(E,~F,2
			F+3Ans->F
	End:End
Lbl SQ:End
For(I,1,60
	real(12,8,0,0,95,63,1
End
rand(100
ClrDraw
ZStandard
ZInteger
real(7,|LSET(2
theta->S
If S>min(|LNIH:Then
	1->W
	S->|LNIH(6
	SortD(|LNIH
	5->dim(|LNIH
End
real(12,3,0,0,95,63,1
real(13,1
Text(~1,1,1,"               
Text(~1,1,89," 
real(13,0
4->M
Goto GO
Lbl M3
real(12,7,0,0,95,63,1
real(12,6,0,7,89,62,1
real(12,7,0,29,89,33,1
Line(Xmin,0,0,0
Text(0,0,"SPACE SNAKE
real(13,1
Text(34,1,"HIGH: ",max(|LSPH
real(13,0
DelVar Srand(100
Lbl theta0
Repeat K=45 or pxl-Test(31,47
	Pxl-On(31,47
	getKey->K
	If max(K={25,34:Then
		not(K=34
		real(4,Ans,1,1
	End
	Text(randInt(0,57),91,"=
	S+pxl-Test(30,47)pxl-Test(32,47->S
	real(4,2,1,1
End
If |LSTAT(2
Goto thetaA
Lbl thetaO
For(I,1,60
	real(12,8,0,0,95,63,1
End
rand(100
real(12,7,0,0,95,63,1
If S>min(|LSPH:Then
	1->W
	S->|LSPH(6
	SortD(|LSPH
	5->dim(|LSPH
End
S->R
int(.3S->S
real(12,3,0,0,95,63,1
real(13,1
Text(~1,1,1,"               
Text(~1,1,89," 
real(13,0
Goto GO
Lbl thetaA
StorePic 1
real(12,7,0,0,95,63,1
real(12,3,0,0,95,63,1
real(13,1
Text(~1,1,1,"You Crashed!   
Text(~1,1,89," 
real(13,0
Text(9,2,"USE APPLE
Text(15,2,"END GAME
Text(27,2,"YOU CAN CONTINUE THE GAME
Text(33,2,"FROM HERE IF YOU USE AN
Text(39,2,"APPLE TO KEEP PLAYING.
Text(51,2,"APPLES: ",|LSTAT(2
9->O
Repeat max(K={21,105
	real(12,8,1,O,94,O+6,1
	Repeat K
		getKey->K
	End
	real(12,8,1,O,94,O+6,1
	max(9,min(15,O+6(K=34)-6(K=25->O
End
real(12,7,0,0,95,63,1
RecallPic 1
If O=15
Goto thetaO
|LSTAT(2)-1->|LSTAT(2
real(12,7,0,30,95,32,1
Goto theta0
Lbl M2
ClrHome
26-2int(2rand->K
SetUpEditor L1,L2
{4->L1:Ans->L2:1->I
0->D
startTmr->theta
For(J,1,|E2
	L1(1->L1(J
	L2(1->L2(J
	Repeat (S!=1 or not(max(T={1,2,3}))) and max(S!=L1 and Ans!=L2
		randInt(1,8->S
		randInt(1,16->T
	End
	Repeat D or (T=Ans and S=L1(I
		Output(S,T,Str6
		Output(1,1,det(1,120-checkTmr(theta))+" 
		If 119<checkTmr(theta
		1->D
		getKey->F
		If Ans=45
		1->D
		F
		If Ans=34 or 2>abs(Ans-25
		Ans->K
		I+1-J(I=J->I
		Output(L1(Ans),L2(Ans)," 
		(K=34)-(K=25)+L1(Ans-(Ans>1
		Ans+8(not(Ans)-(Ans=9->L1(I
		(K=26)-(K=24)+L2(I-(I>1
		Ans+16(not(Ans)-(Ans=17->L2(I
		Output(L1(I),Ans,Str5
	End
	If not(D
End
J->S
For(J,1,4
	For(I,1,dim(L1
		Output(L1(I),L2(I),sub("plotsquareplotcrossplotdot ",J,1
End:End
rand(100
ClrHome
If S>min(|LDMH:Then
	1->W
	S->|LDMH(6
	SortD(|LDMH
	5->dim(|LDMH
End
Goto GO
Lbl M1
ClrHome
26->K
1.1->B
SetUpEditor A
{4Ans->A
0->D
For(A,1,|E2
	randInt(1,16)+.1randInt(1,8->C
	Repeat D or C=Ans(1
		A->dim(|LA
		|LA(1
		Output(10fPart(Ans),int(Ans),Str5
		Output(10fPart(B),int(B)," 
		Output(10fPart(C),int(C),Str6
		getKey->F
		If Ans=45
		1->D
		F
		If Ans=34 or 2>abs(Ans-25
		Ans->K
		|LA(A->B
		|LA(1)+(K=26)-(K=24)+.1((K=34)-(K=25->E
		If max(|LA=Ans
		1->D
		E
		Ans+16(not(int(Ans))-(17=int(Ans)))+.8(not(fPart(Ans))-(.9=fPart(Ans
		augment({Ans},|LA->A
	End
	augment(Ans,{Ans(A->A
	If not(D
End
For(J,1,4
	For(I,1,dim(|LA
		|LA(I
		Output(10fPart(Ans),int(Ans),sub("plotsquareplotcrossplotdot ",J,1
End:End
Output(10fPart(C),int(C),Str6
rand(100
ClrHome
A->S
DelVar |LA
If S>min(|LNMH:Then
	1->W
	S->|LNMH(6
	SortD(|LNMH
	5->dim(|LNMH
End
Goto GO
Lbl S
SetUpEditor L1,L2
{0,5,4,9,8,12,17,20,16,17,15,27,30,36,42,48,39,35,56,60->L1
{0,1,2,3,5,9,12,9,18,21,19,22,22,30,32,35,40,45,18,50->L2
real(13,1
Text(~1,1,1,"Store          
real(13,0
real(12,7,1,9,94,62
Text(9,2,"BUY SKINS
Text(15,2,"BUY FOOD
Text(21,2,"EXCHANGE
Text(27,2,"EXIT
For(I,Ymin,~19
	Line(Xmin,I,0,I
End
real(13,1
|LSTAT
Text(50,2,Ans(1),"G
Text(56,2,"APPLES: ",Ans(2
real(13,0
getDate
dayOfWk(Ans(1),Ans(2),Ans(3->D
If max(D={6,7,1:Then
	Text(50,49,"STORE SALE!
	Text(56,49,"ITEMS 30% OFF
	int(.7L1->L1
	int(.7L2->L2
End
getDate
Text(43,2,sub("SUNMONTUEWEDTHUFRISAT",3D-2,3),", ",sub("JANFEBMARAPRMAYJUNJULAUGSEPOCTNOVDEC",3Ans(2)-2,3)," ",Ans(3
9->O
|LSTAT(1->G
|LSTAT(2->A
Repeat max(K={21,105
	real(12,8,1,O,94,O+6,1
	Repeat K
		getKey->K
	End
	real(12,8,1,O,94,O+6,1
	max(9,min(27,O+6(K=34)-6(K=25->O
End
If O=9
Goto C1
If O=15
Goto C2
If O=21
Goto C3
For(I,~19,Ymin,~1
	Line(~46,I,0,I,0
End
Goto M
Lbl C2
real(12,7,1,9,93,49,1
real(13,1
Text(~1,1,1,"Buy Food       
real(13,0
Text(9,2,"BUY FOOD FOR YOUR SNAKE!
Text(15,4,"HAVE:
Text(21,4,"COST:
1->O
Lbl 0Z
Repeat max(K={21,31,45,105,41
	Text(15,22,|LFOD(O),"   
	Text(21,22,L2(O),"G   
	Text(~1,29,6,"[<|]",sub(Str2,O,1),"[|>]
	Repeat K
		getKey->K
	End
	max(1,min(20,O+(K=26)-(K=24->O
End
If K=45
Goto S
If K=41
Goto PF
If O!=1 and K=31 and |LFOD(O:Then
	real(13,1
	|LFOD(O)-1->|LFOD(O
	For(I,1,L2(O
		G+1->G
		Text(50,2,Ans,"G
	End
	real(13,0
	G->|LSTAT(1
End
If K=31
Goto 0Z
If G<L2(O
Goto 0Z
If 99=|LFOD(O
Goto 0Z
1+|LFOD(O->|LFOD(O
real(13,1
For(I,1,L2(O
	G-1->G
	Text(50,2,Ans,"G   
End
real(13,0
G->|LSTAT(1
Goto 0Z
Lbl PF
StorePic 1
real(12,7,2,27,93,35,1
real(12,3,2,27,93,35,1
Text(28,4,"SELLING ALL FOOD.
For(I,2,20
	If |LFOD(I:Then
		|LFOD(I->N
		G+NL2(I->G
		0->|LFOD(I
End:End
G->|LSTAT(1
real(12,7,2,27,93,35
RecallPic 1
real(13,1
Text(50,2,G,"G
real(13,0
Goto 0Z
Lbl C1
real(12,7,1,9,93,49,1
real(13,1
Text(~1,1,1,"Buy Skins      
real(13,0
Text(9,2,"BUY SKINS FOR YOUR SNAKE!
Text(15,4,"HAVE:
Text(21,4,"COST:
1->O
Lbl Z0
Repeat max(K={21,31,105,45,41
	Text(15,22,|LSKN(O),"   
	Text(21,22,L1(O),"G   
	Text(~1,29,6,"[<|]",sub(Str1,O,1),"[|>]
	Repeat K
		getKey->K
	End
	max(1,min(20,O+(K=26)-(K=24->O
End
If K=45
Goto S
If K=41
Goto PS
If O!=1 and K=31 and |LSKN(O:Then
	|LSKN(O)-1->|LSKN(O
	real(13,1
	For(I,1,L1(O
		G+1->G
		Text(50,2,Ans,"G
	End
	real(13,0
	G->|LSTAT(1
End
If K=31
Goto Z0
If 99=|LSKN(O
Goto Z0
If G<L1(O
Goto Z0
real(13,1
1+|LSKN(O->|LSKN(O
For(I,1,L1(O
	G-1->G
	Text(50,2,Ans,"G   
End
real(13,0
G->|LSTAT(1
Goto Z0
Lbl PS
StorePic 1
real(12,7,2,27,93,35,1
real(12,3,2,27,93,35,1
Text(28,4,"SELLING ALL SKINS.
For(I,2,20
	If |LSKN(I:Then
		|LSKN(I->N
		G+NL1(I->G
		0->|LSKN(I
	End
End
G->|LSTAT(1
real(12,7,2,27,93,35,1
RecallPic 1
real(13,1
Text(50,2,G,"G
real(13,0
Goto Z0
Lbl C3
real(12,7,1,9,43,49,1
real(13,1
Text(~1,1,1,"Exchange
real(13,0
Text(9,2,"EXCHANGE BETWEEN GOLD
Text(15,2,"AND APPLES.
Text(21,2,"10 GOLD = 1 APPLE
Text(28,44,"[<|][|>]APPLES
Text(28,28,"GOLD
|LSTAT(1->G
|LSTAT(2->A
real(13,1
Repeat max(K={21,105
	Text(50,2,G,"G   
	Text(56,29,A,"   
	Repeat K
		getKey->K
	End
	If K=24 and A:Then
		G+10->G
		A-1->A
	End
	If K=26 and G>9:Then
		G-10->G
		A+1->A
End:End
G->|LSTAT(1
A->|LSTAT(2
Goto S
Lbl HS
real(13,1
Text(~1,1,1,"               
real(13,0
real(12,7,1,9,94,62,1
SetUpEditor L1
For(J,1,4
	real(13,1
	|LNMH->L1
	"Normal
	If J=2:Then
		|LDMH->L1
		"Dimented
	End
	If J=3:Then
		|LSPH->L1
		"Space   
	End
	If J=4:Then
		|LNIH->L1
		"Nibbles
	End
	Text(~1,1,1,Ans
	real(13,0
	For(I,1,5
		{9,15,21,27,33
		Text(Ans(I),2,I,") ",L1(I),"               
	End
	Text(39,2,"AVG: ",int(mean(L1)),"               
	Pause 
End
Goto M
Lbl MD
real(13,1
Text(~1,1,1,"My Data|       
Text(1,47,Str4
real(13,0
real(12,7,1,9,94,62,1
|LSTAT
Text(9,2,Ans(1),"G
Text(15,2,"APPLES: ",Ans(2
Text(23,4,"SKIN:
Text(~1,23,22,sub(Str1,Ans(3),1
Text(23,28,"x",|LSKN(Ans(3
Text(31,4,"FOOD:
Text(~1,31,22,sub(Str2,Ans(4),1
Text(31,28,"x",|LFOD(Ans(4
real(12,3,0,60,95,63,1
Text(39,6,"LEVEL
|LLVL
Text(~1,39,37,Ans(2
Text(53,2,Ans(1)," / ",Ans(3
int(100Ans(1)/Ans(3
int(Ans%94
real(12,6,0,60,Ans,63,1
Pause 
Goto M
Lbl RS
real(13,1
Text(~1,1,1,"Reset What?    
real(13,0
real(12,7,1,9,94,62,1
Text(9,2,"SNAKE STATS
Text(15,2,"GAMEPLAY STATS
Text(21,2,"HIGH SCORES
Text(27,2,"DEFAULT SETTINGS
Text(33,2,"ALL DATA
Text(39,2,"NOTHING
9->O
Repeat max(K={21,105
	real(12,8,1,O,94,O+6,1
	Repeat K
		getKey->K
	End
	real(12,8,1,O,94,O+6,1
	max(9,min(39,O+6(K=34)-6(K=25->O
End
If O=39
Goto OP
Text(56,2,"RESETTING...
If O=9:Then
	{20,10,1,1,0->STAT
	Fill(0,|LSKN
	Fill(0,|LFOD
	99->|LSKN(1
	Ans->|LFOD(1
End
If O=15
{0,1,25,0->LVL
If O=21:Then
	Fill(0,|LNMH
	Fill(0,|LNIH
	Fill(0,|LSPH
	Fill(0,|LDMH
End
If O=27:Then
	{23,0,1,0,0->SET
	"SNAKES->Str4
End
If O!=33
Goto RS
det(0,4,Str9
real(13,1
Text(~1,1,1,"All Data Reset!
real(13,0
real(12,7,1,9,94,62,1
Text(9,2,"ALL DATA FOR SNAKE ARCADE
Text(15,2,"HAS BEEN RESET. A NEW
Text(21,2,"USER MUST BE REGISTERED.
Pause 
ClrDraw:ClrHome
Return
Lbl S3
Text(45,62,"-                            
StorePic 1
real(12,7,2,24,93,38,1
real(12,3,2,24,93,38,1
Text(25,4,"INPUT NEW NAME:
Repeat length(Str4) and max(K={21,105
	"|   
	If length(Str4
	Str4+Ans
	Text(31,4,Ans
	Repeat K
		getKey->K
	End
	If 10>length(Str4) and (K>34 and K<95 and not(max(K={44,45:Then
		sub("ABC  DEFGHIJKLMNOPQRSTUVWXYZ_",K-5int(.1K)-20,1
		If length(Str4
		Str4+Ans->Str4
		If not(length(Str4
		Ans->Str4
	End
	If K=23:Then
		If 1=length(Str4
		"->Str4
		If 1<length(Str4
		sub(Str4,1,length(Str4)-1->Str4
	End
	If K=45:Then
		"->Str4
		real(12,7,4,31,92,37,1
	End
End
real(12,7,2,24,93,38,1
RecallPic 1
DelVar Pic1
Goto S0
Lbl S2
Text(15,58,"[<|]
Text(15,70,"[|>]
real(5->theta
|LSET(1->C
Repeat max(K={21,105
	Text(15,62,C
	real(5,0,C
	Repeat K
		getKey->K
	End
	max(10,min(39,C+(K=26)-(K=24->C
	If K=31
	theta->C
End
Text(15,58,"   
Text(15,70,"   
C->|LSET(1
real(5,0,theta
Goto S0
Lbl S1
StorePic 1
real(12,7,2,22,93,40,1
real(12,3,2,22,93,40,1
|LSTAT(3->A
|LSTAT(4->B
Text(24,4,"SKIN
Text(32,4,"FOOD
24->O
Repeat max(K={21,105
	Text(~1,24,49,sub(Str1,A,1
	Text(~1,32,49,sub(Str2,B,1
	real(12,8,3,O,47,O+6,1
	Repeat K
		getKey->K
	End
	real(12,8,3,O,47,O+6,1
	max(24,min(32,O+8(K=34)-8(K=25->O
	If max(K={24,26:Then
		If O=24:Then
			Repeat |LSKN(A
				A+(K=26)-(K=24->A
				A+20(not(A))-20(A=21->A
			End
		End
		If O=32:Then
			Repeat |LFOD(B
				B+(K=26)-(K=24->B
				B+20(not(B))-20(B=21->B
			End
		End
	End
End
real(12,7,2,22,93,40,1
RecallPic 1
DelVar Pic1
9->O
A->|LSTAT(3
B->|LSTAT(4
Goto S0
Lbl Q
real(13,1
Text(~1,1,1,"               
real(12,7,1,9,94,62,1
1->S
If |LSET(4:Then
	Text(~1,1,1,"Overwrite Save?
	real(13,0
	Text(9,2,"YES
	Text(15,2,"NO
	Text(27,2,"THE PREVIOUS SAVED DATA
	Text(33,2,"WILL BE OVERWRITTEN!
	9->O
	Repeat max(K={21,105
		real(12,8,1,O,94,O+6,1
		Repeat K
			getKey->K
		End
		real(12,8,1,O,94,O+6,1
		max(9,min(15,O+6(K=34)-6(K=25->O
	End
	O=9->S
	real(12,7,1,9,94,62,1
	real(13,1
End
If S:Then
	Text(~1,1,1,"Saving Data... 
	real(13,0
	Text(9,2,"WRITING DATA.
	sub(det(0,7,Str9),1,1
	If Ans="A
	det(0,Str9
	real(12,3,0,60,95,63,1
	For(I,1,10
		|LSTAT
		If I=2
		|LSET
		If I=3
		Str4
		If I=4
		|LLVL
		If I=5
		|LNMH
		If I=6
		|LNIH
		If I=7
		|LSPH
		If I=8
		|LDMH
		If I=9
		|LSKN
		If I=10
		|LFOD
		If I!=3
		det(1,Ans
		det(8,Str9,det(18,Ans),I
		int(100I/10
		int(Ans%94
		real(12,6,0,60,Ans,63,1
End:End
real(13,0
sub(det(0,7,Str9),1,1
If |LSET(3) and Ans="R":Then
	real(13,1
	Text(~1,1,1,"Archiving...   
	real(13,0
	Text(9,2,"ARCHIVING APPVAR.
	det(0,Str9
End
DelVar |LSTATDelVar |LSETDelVar Str4DelVar |LLVLDelVar |LNMHDelVar |LNIHDelVar |LSPHDelVar |LDMHDelVar |LSKNDelVar |LFOD
DelVar Str1DelVar Str2DelVar Str9DelVar Str3DelVar Str4DelVar Str5DelVar Str6DelVar Str0DelVar Str9
ClrDraw
ClrHome
Return